Bis vor Kurzem habe ich noch FastStone Capture als mein Windows Screenshot Utility genutzt. Die Software wurde irgendwann kostenpflichtig und ich blieb dann auf der letzten kostenlosen Version des Programms sitzen.
Letztens las ich auf lifehacker von einer angeblich guten Screenshot Freeware: PicPick!

Ich habe die Software mittlerweile auf all meinen Computern installiert und bin wirklich überzeugt; die Software kann alles, was man von einem Screenshot Utility erwartet!

Übersichtliche Oberfäche in modernem Design:

Oberfläche, Nutzung und Dialoge an das bekannte Office Ribbon angelehnt:

Komplexer Bildeditor mit vielen Funktionen, Formen, Effekten, guter Handhabung, einfach top:

Vielen Einstellungsmöglichkeiten, u.A. automatischer FTP Server Upload und wichtige Shotcuts:

Wer also eine solche Freeware sucht, mit seiner aktuellen Software nicht so zufrieden ist oder einfach den King der Screenshots testen möchte: PicPick ist euer Kandidat!

Ich habe bereits vor einigen Monaten mal über die Erkennung von laufenden Prozessen via Batch geschrieben. Damals habe ich diese Erkennung in einfachen oder komplexeren If Else Blöcken verschachtelt. Ich habe nun gemerkt, dass dies zu Problemen und falschen Erkennungen führen kann!

Daher hier das Update: If Else Verschachtelungen können zwar ein paar Zeilen sparen aber verfälschen Errorlevel Rückgaben! In If Else Blöcken würde ich keine Programmbefehle schreiben, die mit dem Errorlevel arbeiten sollen. Lieber mit einigen gotos arbeiten.

Hier ein Beispiel:

REM Statt:
if /i %action%==start-server (
 tasklist |find /i "IQB_Server.exe"
 if not %errorlevel%==0 start IQB_Server.exe
 goto end
)

REM folgenden Code verwenden:
if /i %action%==start-server goto start-server
:start-server
 tasklist |find /i "IQB_Server.exe"
 if not %errorlevel%==0 start IQB_Server.exe
 goto end

REM Errorlevel in IF ELSE Blöcken können falsch sein!

Nochmal zum Erkennen von Prozessen via Batch: hier sind 3 verschiedene funktionierende Methoden:

REM %errorlevel% ist immer 0 wenn der Prozess existiert
REM 1 wenn nicht gefunden
REM am besten mit 'if not "%errorlevel%"=="0"' überprüfen

REM Variante 1:
tasklist | find /i "dropbox.exe"

REM Variante 2:
tasklist /FI "IMAGENAME eq dropbox.exe" 2>NUL | find /I /N "dropbox.exe">NUL
REM beide NUL Umleitungen optional

REM Variante 3:
tasklist /nh /fi "imagename eq dropbox.exe" | find /i "dropbox.exe" >NUL
REM letzte NUL Umleitung optional

English Version

A few months ago I already wrote a post about the detection of running processes with batch. In this post I used this detection code inside simple or more complex if-else block statements. I recently noticed possible false positives if doing so. Using %errorlevel% return codes inside if-else statements can lead to wrong return codes.

So, here’s the update: if else structures can save a few code lines but can also falsify errorlevel return codes! And since the detection of running processes rely on errorlevel returns you should use gotos instead of if else.

Here’s a code example:

REM instead of:
if /i %action%==start-server (
 tasklist |find /i "IQB_Server.exe"
 if not %errorlevel%==0 start IQB_Server.exe
 goto end
)

REM use this code:
if /i %action%==start-server goto start-server
:start-server
 tasklist |find /i "IQB_Server.exe"
 if not %errorlevel%==0 start IQB_Server.exe
 goto end

REM errorlevel return codes in if-else blocks may be wrong!

Here are 3 different working code examples for process detection:

REM %errorlevel% is always 0 if the process is running
REM and 1 if it is not running
REM best way is to check with 'if not "%errorlevel%"=="0"'

REM code 1:
tasklist | find /i "dropbox.exe"

REM code 2:
tasklist /FI "IMAGENAME eq dropbox.exe" 2>NUL | find /I /N "dropbox.exe">NUL
REM both NUL redirections are optional

REM code 3:
tasklist /nh /fi "imagename eq dropbox.exe" | find /i "dropbox.exe" >NUL
REM last NUL redirection is optional

via, via

Das Ziel sind Screenshots von Webseiten, mit einem Batch Script automatisiert und kontrolliert. Keep it simple & stupid.

Die Wichtigste ist natürlich das Anfertigen der Screenshots. Das ließe sich vermutlich auch mit pure Batch erledigen, ich fand allerdings folgende Utilities besonders einfach und optimal für diesen Zweck: CutyCapt und IECapt. Beide Tools bestehen nur aus einer kleinen .exe Datei und sind kommandozeilenbasiert, optimal für eine Batch Benutzung.
CutyCapt fertigt Website Screenshots mit der WebKit Engine (Chrome und Opera nutzen diese Engine) an, IECapt nutzt die Engine des Internet Explorers.

Die Anwendung ist relativ einfach, über die CMD. Ein Beispiel:

CutyCapt.exe --url=http://www.spiegel.de/ --out=spiegel.png --min-width=1100 --min-height=800 --delay=1000

Wenn die Webseite besonders lang ist so wird sie komplett aufgenommen. Die Parameter steuern das Verhalten der Engine, beim IE gibt es nicht ganz so viele Möglichkeiten.

Das kann man jetzt in einem netten Script verpacken und schon lassen sich beliebige Webseiten mit einem Doppelklick fotografieren. Versehen mit Logging, Mailer und ein paar Kleinigkeiten, fertig.

Hier mein Script, welches 2 Screenshots der Fritz Box aufnimmt, in einem Unterordner speichert, eine Mail schickt und alles loggt, so als Muster:

Code anzeigenDen Code könnt ihr bequem mit den Links/Rechts Pfeiltasten horizontal bewegen.

@echo off
setlocal
Color 9f

REM ### INFORMATIONS ############################################

REM ****************************************************
REM  Title:   	Website Screenshot Daemon (WSD)
REM  Author:  	Hannes Schurig
REM  Created: 	22.02.2013
REM  Changed: 	25.02.2013
REM  Version: 	0.3.5
REM  Changelog: 0.1: complete mailer function with flexible callback
REM				0.1.1: complete new mailer with call, parameters and no local variables, 50% less code
REM				0.2: CutyCapt configured to take 2 screenshots, formatted datetime filename
REM				0.2.1: collect errorlevels and added to mail text
REM				0.2.2: save screenshots in subfolder, check if exist, create if needed
REM				0.3: use working directory and absolute paths for sheduling compatibility
REM				0.3.1: script renamed, detect working directory and filename
REM				0.3.2: removed usesubdir variable, remove 40-45 and edit 51 & 53 for no subdir
REM				0.3.3: fixed bug - spaces in working path lead to script malfunction
REM				0.3.4: CutyCapt parameters as variable - they do not change
REM				0.3.5: added 20 seconds max-wait parameter
REM  Credits: CutyCapt website screenshot utility: http://cutycapt.sourceforge.net/ - awesome!
REM ****************************************************

REM ### VARIABLES ############################################

for %%a in (%0) do set filename=%%~nxa
for %%a in (%0) do set wd=%%~dpa
REM remove last "\" or "/" from working directory (wd) path
if "%wd:~-1%"=="\" set wd=%wd:~0,-1%
if "%wd:~-1%"=="/" set wd=%wd:~0,-1%
set subdir=%wd%\screenshots
set mailer=1
set adminmail=hannes.schurig@online.de
set log="%wd%\logfile.txt"
set cutycapt="%wd%\CutyCapt.exe"
set datetime=0
set scerrorlevel=0

REM same parameters for every screenshot? It's shorter with:
set cutycaptparameters=--min-width=1100 --min-height=800 --delay=1000 --max-wait=20000

REM ### PROGRAM START ############################################

echo %date% - %time:~0,5% (i) WSD starting... >> %log%

REM check and create subdir if wanted and needed
if not "%subdir%"=="" (
	if not exist "%subdir%" (
		md "%subdir%"
	)
)

REM prepare short datetime with . instead :
set datetime=%date%-%time:~0,5%
set datetime=%datetime::=.%

%cutycapt% --url=http://fritz.box/ --out="%subdir%/%datetime%-dashboard.png" %cutycaptparameters%
set scerrorlevel=%errorlevel%
%cutycapt% --url=http://fritz.box/system/syslog.lua --out="%subdir%/%datetime%-events.png" %cutycaptparameters%
set scerrorlevel=%scerrorlevel%%errorlevel%

echo %date% - %time:~0,5% (i) Screenshot taken with errorlevel %scerrorlevel% >> %log%

echo %date% - %time:~0,5% (i) Sending admin mail... >> %log%
if %mailer%==1 call :mailer "WSD" "Status" "noreply@WSD.com" "Script finished with errorlevel %scerrorlevel%"

:shutdown
echo %date% - %time:~0,5% (i) WSD shutting down... >> %log%
goto end


REM ### MAILER FUNCTION ############################################

:mailer
start iexplore "http://php.webmailer.de/webmail.php&mailto=%adminmail%&contactname=%~1&subject=%~2&email=%~3&message=%~4"
REM wait and close
ping 127.0.0.1 -n 5 > nul
taskkill /im "iexplore.exe" /f
ping 127.0.0.1 -n 3 > nul

REM ### PROGRAM EXIT ############################################

:end
endlocal

Anmerkungen dazu:
Keine Unterordner? Löscht Zeile 49-54 und passt den “–out” Parameter in Zeile 60 und 62 an. Wenn doch, passt Zeile 28 an.
IECapt statt CutyCapt? In Zeile 38 den Dateinamen anpassen.
Der Mailer muss natürlich angepasst werden. Habt ihr einen PHP Webmailer? Dann passt die Zeilen 36, 68 und 78 an. Wenn ihr keinen Mailer habt reicht es die Zeile 35 auf 0 zu setzen.
Ansonsten müsste das funktionieren.

Alternativ zu diesem Script gibt es auch Browser Plugins mit denen Website Screenshots erstellt werden können. Awesome Screenshot wäre ein Google Chrome Plugin für diesen Zweck. Die Extension fotografiert einen ausgewählten Bereich, den sichtbaren Bereich oder die komplette Seite. Das Bild lässt sich bearbeiten, speichern, teilen und mehr.
Über die Automatisierung dieser Geschichte muss man sich dann aber noch Gedanken machen, das ist vermutlich etwas schwieriger.

Bugs, Anmerkungen sowie Verbesserungsvorschläge nehme ich natürlich gerne entgegen.

Ich hatte in letzter Zeit öfter mit der Installation von Windows 7 auf älteren Computern zu tun. Damit meine ich Computer mit 1,6GHz Single Core, 1GB RAM, onboard Grafik und einer 40GB Festplatte.
Hier zusammengefasst ein paar Tipps & Tricks, die bei der Installation und Optimierung eines Windows 7 auf solchen Uralt-PCs helfen.

Wie viel Platz braucht Windows 7?
Je nach Version (Starter, Home, Pro, Enterprise) und je nach Architektur (32, 64) benötigt eine blanke Installation von Windows zwischen 4GB und 9GB Speicherplatz. Hinzu kommen die 2 Daten für die Auslagerung und den Ruhestand (pagefile und hyberfil), für gewöhnlich jeweils so groß wie der eingebaute RAM. Also ein frisch installiertes Windows 7 Home Premium 32bit mit 1,5GB RAM verbraucht etwa 7-8GB (4-5GB + 1,5GB + 1,5GB). Nun kommen noch große Datenmengen an Treibern, Windows Updates und temporären Daten hinzu. Dieses frisch installierte Windows 7 wächst von seinen 7-8GB auf 13GB allein nur durch die Installation aller Windows Updates und Service Pack 1 (Stand Feb 2013). Dazu kommen jetzt noch Treiber und Standardprogramme wie DirectX, Flash, Java, etliche Frameworks usw, die zum Betrieb aktueller Software oder Internetseiten gebraucht werden; 14-15GB für ein ausgestattetes System kann man also einplanen. Deswegen spricht Microsoft von einer Mindestanforderung von 16GB diese sind mindestens zu empfehlen. 20GB oder besser 30GB sollte die Partition fassen, wenn das System zukunftstauglich eingerichtet werden soll. Denn es folgen sicher weitere Updates, die Computerbenutzung schafft schnell neue Datenmengen, das Entpacken von Archiven benötigt ebenfalls temporären Platz auf der Systempartition.

Sollte ich alle Updates installieren?
Je nach Festplattenplatz und Nutzung des Computers empfiehlt es sich, die Windows Updates zumindest einmalig vollständig zu installieren. Updates sollen in erster Linie ja die Sicherheit und Stabilität verbessern. Aber auch wenn der Computer nicht in’s Internet gehen soll, also Sicherheit nicht so relevant ist, gibt es viele Updates die bestimmte Funktionen von Windows nachrüsten (z.B. die Erkennung von SD Karten mit mehr als 32GB) oder Voraussetzungen installieren (.NET Framework), die für den täglichen Gebrauch nützlich oder erforderlich sind.
Das Deaktivieren der Windows Updates verschafft dem PC etwas mehr Power für die eigentliche Arbeit. Wer auf Sicherheit setzt aktiviert die Updates monatlich oder halbjährig und installiert alles, deaktiviert die Funktion danach wieder.
Wenn die Partition zu klein wird empfiehlt es sich die Sicherungsdateien der vielen Updates zu löschen. Startet die “Datenträgerbereinigung” des Systemlaufwerks und lasst die “Service Pack Sicherungsdateien” aufräumen.

Performance-Tuning im “Leistungsinformationen- und tools” (einfach in der Startmenü Suche eingeben):

Visuelle Effekte optimieren -> Für optimale Leistung anpassen: deaktiviert alle grafischen Spielereien, die vor allem Computer mit alter CPU und onboard Grafik in die Kniehe zwingen. Einzelne Effekte können auf Wunsch aktiviert werden, wenn man darauf Wert setzt. Zum Beispiel empfinden viele Menschen es als besonders anstrengend den Effekt “Kanten der Bildschirmschriftarten verfeinern” zu deaktivieren. Wer nicht den kompletten Uralt Style erträgt kann auch “Visuelle Stile für Fenster und Schaltflächen” wieder aktivieren.

Indizierungsoptionen anpassen -> Der Indizierungsdienst verbessert die Windows Suche durch das ständige Durchsuchen von Daten. Das kostet dauerhaft Leistung und hilft eher selten. Ich deaktiviere diesen Dienst auf den meisten PCs.
Entweder über “Dienste” -> “Windows Search” -> Beenden & Starttyp auf Deaktiviert stellen oder über die CMD mit den 2 Befehlen:
net stop wssearch
sc config wsearch start= disabled

Datenträgerbereinigung öffnen -> Wenn der PC normal läuft und auch noch einigen Neustarts wie gewünscht funktioniert kann man in der Datenträgerbereinigung einige überflüssige Daten loswerden. Am größten wird der Posten “Service Pack Sicherungsdateien” sein, aber auch die “Temporary Internet Files” und die Einträge der Fehlerberichterstattung können noch einige Megabyte enthalten. Lasst diese Punkt von Windows mal bereinigen. Alternativ ist auch der CCleaner ein super Tool zum Aufräumen.
Unter Windows XP gibt es im Ordner C:\Windows die berühmten $NtUninstall und $NtServicePackUninstall Ordner. Auch die können Weg um Speicher freizugeben, wenn alles läuft.

Dienste deaktivieren:
Dies ist immer ein kritischer Part, hier muss jeder selber entscheiden wie wichtig die Stabilität des Systems gegenüber dem Performancegewinn ist.

Hier eine Liste der Windows Dienste, die man (zumindest laut dem Autor des verlinkten Artikels) deaktivieren könnte: LINK.
Und noch eine Liste aller Dienste mit ihren Funktionen, empfohlenen Einstellungen und möglichen Nachteilen: LINK.

Allgemein kann man im “Dienste” Dialog von Windows jeden Dienst erst Beenden (falls er läuft) und dann den Starttyp auf Manuell oder deaktiviert setzen.
Ich habe kaum einen Dienst deaktiviert (Windows Search, Design), kann hier also nicht viele Tipps geben. An dieser Stelle werde ich mich aber nochmal belesen und sicher ein paar Dienste wie Windows Error Reporting Service oder Windows Media Center Service Launcher nochmal überdenken. Denn außerhalb der Arbeit benötige ich viele Funktionen wirklich nicht.

Systemstart überprüfen:
Eine gute alte Möglichkeit die Leistung und vor allem den Systemstart zu erhöhen ist das Aufräumen der Autostart-Programme. Diese Programme werden automatisch mit Windows gestartet und bleiben meistens dauerhaft aktiv.

Das Tool “msconfig” enthält den Tab “Systemstart” und listet dort alle Programme auf, die mit Windows gestartet werden können. Alle gesetzten Haken zeigen aktive Autostarts an und sollten überprüft werden. Hier erfordert es ein wenig IT Hintergrund wissen, überflüssige Programme auszusortieren. Die Startup Application Knowledge Base verrät zur Not Informationen zu bekannteren Programmen.

Unbenötigte Windows Funktionen deaktivieren:
Viele Funktionen sind standardmäßig aktiviert, bleiben aber unbenutzt. Diese Liste der Funktionen findet ihr über die Startmenü Suche via “Windows-Funktionen aktivieren oder deaktivieren”, auch ein Menüpunkt in “Programme und Funktionen”.

Schaut die aktivierten Listenpunkte durch und deaktiviert auf Wunsch die Punkte. Ein Tooltip (bei Mouseover) verrät oftmals ausreichend, wofür die Funktion zuständig ist.
Ich habe Funktionen wie “Internetdruckclient”, “Windows DVD Maker”, “Windows Media Center”, “Plattform zu Windows-Minianwendungen”, “Remoteunterschiedskomprimierung” und “Tablet-PC-Komponenten” deaktiviert.

Update: Achtung! An dieser Stelle nicht “Windows Search” deaktivieren, dann verschwindet die Suchleiste im Startmenü. Windows Search nur unter “Dienste” deaktivieren.

Kleinkram:

Protokollierung deaktivieren: in der Registry unter HKEY_LOCAL_MACHINE\Software\Microsoft\WBEM\CIMOM die Einträge “EnableEvents” und “Logging” auf 0 setzen.

Werbeblocker: Werbung im Internet ist nicht nur anstrengend und nervig, sie verlangsamt auch den Aufbau einer Internetseite. Installiert Werbeblocker wie Adblock Plus in eurem Browser!

Registry Fehler suchen: CCleaner, RegCleaner und viele andere Programme suchen in der Registry nach fehlerhaften Einträgen und bereinigen diese. Das kann die Performance ebenfalls leicht verbessern.

Unnötige Programme deinstallieren: Programme und FUnktionen aufrufen und unnötige Programme deinstallieren, logisch.

Tuning Tools:
Das alles ist viel Arbeit und Fummelei, einige wenige kostenlose Tools übernehmen viele dieser Tuning Tipps. Für das Windows Tweaking ist aber 1 Freeware besonders gut geeignet und sehr zu empfehlen: Ultimate Windows Tweaker. Die kleine .exe Datei ist sehr mächtig, über 150 Tweaks können angewendet werden, sollte aber mit Vorsicht benutzt werden.

via, via, via, via, via

Es ist wieder soweit, kürzlich veröffentlichte Mozilla die neue Version der Firefox ESR (Extended Support Release) Variante. Firefox 17.0.2 ESR ist vor allem für das Deployment in Unternehmen gedacht, wenn Stabilität und Sicherheit des Browsers wichtiger sind als neue Features und Spielereien.

Ich möchte kurz meine Verteilung hier für andere Administratoren bereitstellen.
Die Verteilung verläuft via Startscript in einer Active Directory Domäne mit 95% 32bit Windows 7 PCs.
Sie hat sich in der kompletten Firefox 10 ESR Reihe bereits als funktionstüchtig erwiesen und wurde seitdem immer wieder verbessert.

Wer sich schon etwas auskennt, hier direkt der Download:

firefox-17-esr [.zip]

Updates:
1.3 – Bug, der die Installation verhinderte, wenn kein Firefox auf dem Client installiert ist, behoben
1.4 – mozilla.cfg um 2 Einstellungen ergänzt, die 2 “Thanks for installing Firefox” und “Congratulations on installing Firefox” Fenster blockt

Das Paket besteht aus folgenden Dateien:
Firefox17.0.2.exe – Setup Datei
firefox-installer.bat – Setup Script
log.txt – Setup Log Datei
mozilla.cfg – Firefox Setup Config Dateien
install.ini – Firefox Setup Config Dateien
override.ini – Firefox Setup Config Dateien
local-settings.js – Firefox Browser Einstellungen, Achtung: neuer Unterordner! siehe unten
deniedPCs.txt – optional: Client Filter Config Datei
allowedPCs.txt – optional: Client Filter Config Datei
VersionCompare.exe – Versionsvergleichstool
VersionCompare-test.bat – kleines Readme- und Test Script für das Versionsvergleichstool

Das Script als Klartext zum Reinlesen:
Code anzeigenDen Code könnt ihr bequem mit den Links/Rechts Pfeiltasten horizontal bewegen.

@echo on
Color 9f
setlocal

REM *******************************************
REM  Title:   	Firefox ESR Silent Installer
REM  Author:  	Hannes Schurig
REM  Created: 	08.12.2011
REM  Changed: 	11.01.2013
REM  Version: 	1.4
REM  Quelle:	http://mockbox.net/configmgr-sccm/174-install-and-configure-firefox-silently.html
REM *******************************************

REM _______________________________________________________________
REM WICHTIG! Hier die aktuelle zu verteilende Version eingeben.
REM Die Installerdatei muss so benannt sein: Firefox[Version].exe
set newversion=17.0.2
REM _______________________________________________________________

set wd=\\server\Firefox
set toolsdir=\\server\Tools
set log=\\server\Firefox\log.txt
set instversion=0.0

REM Clientfilter: nur die Computer aus der allowedPCs.txt dürfen installieren
::for /f %%f in (%wd%\allowedPCs.txt) do if "%computername%"=="%%f" goto install
::goto end

REM Clientfilter: die Computer aus der deniedPCs.txt dürfen nicht installieren
for /f %%f in (%wd%\deniedPCs.txt) do if "%computername%"=="%%f" goto end

:install
title Firefox Installation wird überprüft...
echo Firefox Installation wird überprüft...

REM prüfe ob eine 32bit Version von Firefox schon installiert ist
for /f "tokens=1,2,3 delims= " %%a in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Mozilla\Mozilla Firefox" /v "CurrentVersion"^|findstr "CurrentVersion"') do set instversion=%%c
REM falls keine 32bit Version von Firefox gefunden wurde, prüfe 64bit
if "%instversion%"=="0.0" for /f "tokens=1,2,3 delims= " %%a in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Mozilla\Mozilla Firefox" /v "CurrentVersion"^|findstr "CurrentVersion"') do set instversion=%%c

REM Version gleich?
if "%instversion%"=="%newversion%" echo %date% %time% - %computername% (%instversion%) hat bereits diese Version installiert. >> %log% & goto end

REM Wenn Version nicht gleich: vergleiche Versionen mit dem Versionchecker
%toolsdir%\VersionCompare.exe %instversion% %newversion%
set versioncompare=%errorlevel%
if %versioncompare%==0 echo %date% %time% - %computername% (%instversion%) hat bereits diese Version installiert. >> %log% & goto end
if %versioncompare%==1 echo %date% %time% - %computername% (%instversion%) hat bereits eine neuere Version installiert. >> %log% & goto end

echo %date% %time% - %computername% (%instversion%) startet die Firefox Installation...
echo %date% %time% - %computername% (%instversion%) startet die Firefox Installation... >> %log%

title Firefox wird installiert...
echo Firefox wird installiert...
REM aktuellste Version hier eintragen
"%wd%\Firefox%newversion%.exe" -ms

REM Install 32-bit customisations
if exist "%programfiles%\Mozilla Firefox\" copy /Y "%wd%\override.ini" "%programfiles%\Mozilla Firefox\"
if exist "%programfiles%\Mozilla Firefox\" copy /Y "%wd%\mozilla.cfg" "%programfiles%\Mozilla Firefox\"
if exist "%programfiles%\Mozilla Firefox\" copy /Y "%wd%\local-settings.js" "%programfiles%\Mozilla Firefox\defaults\preferences"

REM Install 64-bit customisations
if exist "%ProgramFiles(x86)%\Mozilla Firefox\" copy /Y "%wd%\override.ini" "%ProgramFiles(x86)%\Mozilla Firefox\"
if exist "%ProgramFiles(x86)%\Mozilla Firefox\" copy /Y "%wd%\mozilla.cfg" "%ProgramFiles(x86)%\Mozilla Firefox\"
if exist "%ProgramFiles(x86)%\Mozilla Firefox\" copy /Y "%wd%\local-settings.js" "%ProgramFiles(x86)%\Mozilla Firefox\defaults\preferences"


REM Removes Firefox Desktop Icon - Windows XP
::if exist "%allusersprofile%\Desktop\Mozilla Firefox.lnk" del "%allusersprofile%\Desktop\Mozilla Firefox.lnk" /S

REM Removes Firefox Desktop Icon - Windows 7
::if exist "C:\Users\Public\Desktop\Mozilla Firefox.lnk" del "C:\Users\Public\Desktop\Mozilla Firefox.lnk"

echo %date% %time% - %computername% hat die Installation abgeschlossen...
echo %date% %time% - %computername% hat die Installation abgeschlossen... >> %log%

:end
endlocal

nötige Änderungen am Script
Zeile 17: die gewünschte Version muss hier stehen, in der “korrekten” Form, wie sie auch in der Registry zu finden ist. Die Installer .exe muss ebenfalls korrekt benannt werden.
Zeile 20-22: Pfade anpassen, Zeile 20+22 müssen auf den Firefox Ordner auf eurem Server/Netzlaufwerk zeigen, Zeile 21 auf den Ordner, der die VersionCompare.exe (im Download enthalten) beinhaltet
Zeile 25-30: Clientfilter, ggf. entfernen wenn nicht gewünscht
Zeile 36-48: Versionsvergleich der installierten Version mit der verfügbaren Version, ggf. anpassen oder entfernen. Aktuell wird die 17.0.2 ESR installiert wenn auf dem PC keine oder eine ältere Version gefunden wurde, nicht aber wenn die gleiche oder eine neue (z.B. 18.0 nicht ESR) gefunden wurde.
Zeile 69-73: Löschen des Desktop Icons ist deaktiviert (Icon bleibt also), ggf. die Kommentarzeichen entfernen

Ein paar zusätzliche Informationen zur Funktionsweise und den Einstellungen findet ihr auch in meinen damaligen Firefox Deployment Posts.

Noch eine Anmerkung: Das Verzeichnis .\defaults\pref\ ist outdated! Dort gelagerte Anpassungsdateien (wie die local-settings.js) werden ignoriert. Diese Anpassungen müssen jetzt in .\defaults\preferences\ abgelegt werden. Dort werden die Änderungen auch beachtet. Von mir getestet und bestätigt. via

Die Verteilung ist getestet und funktioniert.
Ein seltsames Problem bleibt jedoch: nach der Verteilung, beim ersten Start des Firefox, wird ein Tab mit dem Hinweis “Your Firefox is out of date” geöffnet. Und das obwohl Hilfe->Über Firefox bestätigt, dass die Version 17.0.2 im esr Channel momentan die aktuellste Version ist. Wenn jemand weiß wie ich das Anzeigen dieses Tabs verhindern kann, bitte Bescheid sagen.

Update: Diese Verteilung funktioniert übrigens auch wieder 1:1 für Thunderbird 17.0.2 ESR, gerade getestet. Einfach das Script an den 2, 3 Stellen wo “FIrefox” zu “Thunderbird” abändern, fertig. Die Anpassungen der mozilla.cfg müssen natürlich weg, die sind Firefox spezifisch. In der .cfg des Thunderbird hab ich aber auch nur 1 Zeile, die die globale Suche deaktiviert: pref(“mailnews.database.global.indexer.enabled”, false);